Leafkiller's 5.04 Feral/Guardian Ovale Script

[Leafkiller]

The latest alpha version of Ovale is 519. The latest released version is 5.0.1

Back to a single Ovale script now that Rake, Shred and Mangle have been rebalanced. This script incorporates the improvements we made while exploring the Rake filler script.

EDIT: This rotation assumes you are using Glyph of Savagery.

Spoiler: show

Code: Select all

# Ovale Optimized Script Leafkiller 5.4
# Ovale source: http://wow.curse.com/downloads/wow-addons/details/ovale.aspx
# Cat Rotation based on Simulationcraft single target default script. Contributions to that have come from many ferals.
# Revision History
# 5.4.21  09/08/2012 Remove extraneous "mine=1". Add "any=1" to the shared debuffs. Move cat script into functions to share code with predictive frame.
# 5.4.20  09/07/2012 Merge in rotation improvements from the Rake script. Add predictive frame.
# 5.4.11  08/31/2012 Track Wild Charge for cats in upper left box.
# 5.4.10  08/31/2012 Remove all TargetDeadIn calls for now.
# 5.4.9   08/30/2012 Added Bear AOE rotation check box
# 5.4.8   08/30/2012 Make bear cooldown buttons hideable
# 5.4.7   08/30/2012 Enrage moved to second icon, track Incarnation, make the second small box track all of the tier 2 spells and track tier 4 spells
# 5.4.6   08/29/2012 Add Savage Roar desync code
# 5.4.5   08/29/2012 Remove cower, incorporate Tinderhoof's bear rotation.
# 5.4.4   08/29/2012 Change TF code to take into account the new T13 4 piece bonus. Try to give Rake more leeway.
#                    Add opportunistic FF after fillers.
# 5.4.3   08/28/2012 Misc small changes to make it more robust per discussion with Tinderhoof
# 5.4.2   08/28/2012 Rudimentary Bear stuff - I need someway to track Mangle...
# 5.4.1   08/27/2012 First version for patch 5.4 - leaving out Guardian and Feral/Bear for the moment
#                    Assume Glyph of Rake and Glyph of Shred
#                    TargetDeadIn seems to be having issues - so removing the calls for now. Won't affect most combat
Define(BERSERK 106951) #cat cd buff
    SpellInfo(BERSERK duration=15 cd=180 )
    SpellAddBuff(BERSERK BERSERK=1 )
Define(FAERIEFERAL 770) #bear+cat
    SpellInfo(FAERIEFERAL duration=300 cd=6)
    SpellAddTargetDebuff(FAERIEFERAL FAERIEFERAL=1 weakened_armor=1)
Define(FEROCIOUSBITE 22568) #cat finish 25-50 energy
    SpellInfo(FEROCIOUSBITE energy=25 combo=-5)
Define(MAIM 22570) #cat interrupt
    SpellInfo(MAIM cd=10 energy=35 combo=-5)
Define(MANGLECAT 33876) #cat bleed+debuff
    SpellInfo(MANGLECAT inccounter=ripshreds energy=35 combo=1)
Define(RAKE 1822) #cat bleed
    SpellInfo(RAKE duration=15 energy=35 tick=3 combo=1)
    SpellAddTargetDebuff(RAKE RAKE=1)
Define(RAVAGE 6785)
  SpellInfo(RAVAGE inccounter=ripshreds energy=45 combo=1)
Define(RIP 1079) #cat bleed
    SpellInfo(RIP resetcounter=ripshreds duration=16 energy=30 tick=2 combo=-5)
    SpellAddTargetDebuff(RIP RIP=1)
Define(SAVAGEROAR 127538) #cat damage buff
    SpellInfo(SAVAGEROAR energy=25 duration=12 combo=-5)
    SpellAddBuff(SAVAGEROAR SAVAGEROAR=1 )
Define(SHRED 5221) #cat behind
    SpellInfo(SHRED inccounter=ripshreds energy=40 combo=1)
Define(SHREDBANG 114236)
    SpellInfo(SHREDBANG inccounter=ripshreds energy=40 combo=1)
Define(SKULLBASHCAT 80965) #cat interrupt
    SpellInfo(SKULLBASHCAT cd=15 energy=15)
Define(THRASHCAT 106830)
    SpellInfo(THRASHCAT duration=15 energy=50 tick=3)
    SpellAddTargetDebuff(THRASHCAT THRASHCAT=1 weakened_blows=1)
Define(TIGERSFURY 5217) #cat buff
    SpellInfo(TIGERSFURY duration=6 energy=-60 cd=30)
    SpellAddBuff(TIGERSFURY TIGERSFURY=1)
Define(WILDCHARGE 49376)
    SpellInfo(WILDCHARGE cd=15)

Define(BERSERKBEAR 106952) #cat+bear cd buff
  SpellInfo(BERSERKBEAR duration=10 cd=180 )
  SpellAddBuff(BERSERKBEAR BERSERKBEAR=1)
Define(MANGLEBEAR 33878)
Define(LACERATE 33745)
Define(FRENZIEDREGEN 22842)
Define(INCARNATIONBEAR 102558)
Define(MAUL 6807)
Define(MIGHTOFURSOC 106922)
Define(RENEWAL 108238)
Define(NATURESSWIFTNESS 132158)
Define(CENARIONWARD 102351)
Define(FORCEOFNATURE 106737)
Define(SAVAGEDEFENSE 62606)
Define(SURVIVALINSTINCTS 61336)
Define(SWIPEBEAR 779)
Define(THRASHBEAR 77758)
Define(BARKSKIN 22812)
Define(ENRAGE 5229)

Define(cat_form 768)
  SpellAddBuff(cat_form cat_form=1)
Define(mark_of_the_wild 1126)
  SpellInfo(mark_of_the_wild duration=3600 )
  SpellAddBuff(mark_of_the_wild mark_of_the_wild=1)
Define(incarnation 102543)
  SpellInfo(incarnation duration=30 cd=180 )
Define(treants 106737)
  SpellInfo(treants duration=15 cd=60 )
Define(weakened_armor 113746)
  SpellInfo(weakened_armor duration=30 )
Define(weakened_blows 115798)
  SpellInfo(weakened_blows duration=30 )
Define(dream_of_cenarius_talent 17)
Define(force_of_nature_talent 12)
Define(incarnation_talent 11)
Define(natures_swiftness_talent 4)
Define(renewal_talent 5)
Define(cenarion_ward_talent 6)
Define(natures_vigil_talent 18)

#Buff
Define(CLEARCASTING 16870)

#Glyphs
Define(GLYPHOFSHRED 114234)

AddCheckBox(berserk "Cat Berserk" default mastery=2)
AddCheckBox(cooldownsL "Show Left Rotation Boxes" default)
AddCheckBox(cooldownsR "Show Right Cooldown Boxes" default)
AddCheckBox(lucioles SpellName(FAERIEFERAL) default mastery=2)
AddCheckBox(infront "Frontal attack"  mastery=2)
AddCheckBox(bearaoe "Bear AOE Rotation" mastery=3)
AddCheckBox(predictive "Hide predictive box" mastery=2)


AddIcon help=cd size=small mastery=3 checkboxon=cooldownsL {
    Spell(BARKSKIN)
}

AddIcon help=cd size=small mastery=3 checkboxon=cooldownsL {
    if TalentPoints(natures_swiftness_talent) Spell(NATURESSWIFTNESS)
    if TalentPoints(renewal_talent) Spell(RENEWAL)
    if TalentPoints(cenarion_ward_talent) Spell(CENARIONWARD)
}

# Main rotation
AddIcon help=main mastery=3 {    
    if CheckBoxOff(bearaoe) {
        if 1s before Spell(MANGLEBEAR) Spell(MANGLEBEAR)

        if not TargetDebuffPresent(weakened_blows any=1) Spell(THRASHBEAR)
        if target.DebuffStacks(weakened_armor any=1) <1 Spell(FAERIEFERAL)
        if TargetDebuffPresent(THRASHBEAR) <4 Spell(THRASHBEAR)

        Spell(LACERATE)
        Spell(FAERIEFERAL)
    }
   
    if CheckBoxOn(bearaoe) {   
        if 1s before Spell(MANGLEBEAR) Spell(MANGLEBEAR)
        Spell(THRASHBEAR)
        Spell(SWIPEBEAR)
    }
}

AddIcon help=defense mastery=3 {
    if Rage(less 11) Spell(ENRAGE useable=1)
    Spell(SAVAGEDEFENSE usable=1)
    Spell(FRENZIEDREGEN)
}

AddIcon help=cd size=small mastery=3 checkboxon=cooldownsR {
    Spell(SURVIVALINSTINCTS)
}

AddIcon help=cd size=small mastery=3 checkboxon=cooldownsR {
    Spell(MIGHTOFURSOC)
}

AddIcon help=cd size=small mastery=3 checkboxon=cooldownsR {
    if TalentPoints(incarnation_talent) Spell(INCARNATIONBEAR)
    if TalentPoints(force_of_nature_talent) Spell(FORCEOFNATURE)
}

AddIcon help=cd size=small mastery=3 checkboxon=cooldownsR {
    Spell(BERSERKBEAR)
}

AddFunction ExtendRip
{
    if TalentPoints(incarnation_talent) Spell(RAVAGE usable=1)
    if CheckBoxOn(infront) {
        if Glyph(GLYPHOFSHRED) and {BuffPresent(TIGERSFURY) or BuffPresent(BERSERK)} Spell(SHRED)
        Spell(MANGLECAT)
    }
    Spell(SHRED)
}

AddFunction AddCombo
{    
    if BuffPresent(CLEARCASTING) and TargetDebuffExpires(THRASHCAT 3) Spell(THRASHCAT)
    ExtendRip()
}

AddFunction BITWRange
{
    {ArmorSetParts(T13 more 1) and TargetLifePercent(less 60)} or TargetLifePercent(less 25)
}
 
AddIcon help=cd size=small mastery=2 checkboxon=cooldownsL {
    if TargetIsInterruptible(yes) {
        Spell(SKULLBASHCAT)
        if ComboPoints(more 1)
            Spell(MAIM)
    }
    Spell(WILDCHARGE)
}
AddIcon help=cd size=small mastery=2 checkboxon=cooldownsL { # Berserk Icon
    if BuffPresent(TIGERSFURY) Spell(BERSERK)
    if 0s before Spell(BERSERK) Texture(Ability_mount_polarbear_white)
}

AddFunction RefreshSavageRoar
{
    if BuffRemains(SAVAGEROAR) <=1 Spell(SAVAGEROAR)

    if ComboPoints(more 0) and BuffExpires(SAVAGEROAR 3) {
        unless ComboPoints(more 4) and TargetDebuffPresent(RIP) and BuffRemains(SAVAGEROAR) >target.DebuffRemains(RIP) Spell(SAVAGEROAR)
    }
}

AddFunction TFBerserk
{    
    # TF + Berserk logic - only show Berserk if both are off of cooldown - everyone should macro TF to their Berserk key
    if not {BuffPresent(BERSERK) or BuffPresent(CLEARCASTING)} {
        if Energy(less 36) and {0s before Spell(TIGERSFURY)} {
            if CheckBoxOn(berserk) Spell(BERSERK)
            Spell(TIGERSFURY)
        }
    }
    
    #In case Berserk was not cast with TF
    if BuffPresent(TIGERSFURY) and CheckBoxOn(berserk) {
        Spell(BERSERK)
    }
}

AddFunction MainRotation
{
    if CheckBoxOn(lucioles) and target.DebuffStacks(weakened_armor any=1) <1 {
        Spell(FAERIEFERAL)
    }

    # Two conditions for FB during Blood of the Water phase
    # Add in FB code for end of fight - only do this is Rip buff is present
    if BITWRange() and TargetDebuffPresent(RIP) {
        if ComboPoints(more 4) Spell(FEROCIOUSBITE)
        if ComboPoints(more 0) and TargetDebuffExpires(RIP 2.9) Spell(FEROCIOUSBITE)        
    }
    #Extends Rip with shred/mangle/ravage
    if TargetDebuffPresent(RIP) and TargetDebuffExpires(RIP 6) and ComboPoints() <5 and Counter(ripshreds less 3)
        unless BITWRange() ExtendRip()
    
    # also extend if we are going to energy cap
    if TargetDebuffPresent(RIP) and TargetDebuffExpires(RIP 6) and 1.4s before Energy(more 99) and Counter(ripshreds less 3)
        unless BITWRange() ExtendRip()
    
    # Time to recast Rip - clip if possible - try to hold off for TF        
    if ComboPoints() >=5 and TargetDebuffExpires(RIP 2) and {BuffPresent(BERSERK) or target.DebuffRemains(RIP)+1.9 <=SpellCooldown(TIGERSFURY) }
        Spell(RIP)

    # FBs during Berserk
    if BuffPresent(BERSERK) {
        if ComboPoints(more 4) and Energy(more 12) and TargetDebuffPresent(RIP 5) and BuffPresent(SAVAGEROAR 3) {
            Spell(FEROCIOUSBITE)
        }
    }

    # clip Rake early if TF is up and rake ramining is less than 9 seconds 
    if TargetDebuffExpires(RAKE 8.9) and BuffPresent(TIGERSFURY) {
        Spell(RAKE)
    }
   
    # intentionally clip Rake to maximize uptime
    if TargetDebuffExpires(RAKE 2.9) and {BuffPresent(BERSERK) or Energy(more 60) or {SpellCooldown(tigers_fury) +0.8 } >=target.DebuffRemains(RAKE)} 
        Spell(RAKE)
}

AddFunction DesyncFB
{    
    if Counter(ripshreds) < 3
    {
        if ComboPoints() >=5 and BuffRemains(SAVAGEROAR) <={target.DebuffRemains(RIP)+6-{Counter(ripshreds)*2}}
            Spell(SAVAGEROAR)
    }
    if Counter(ripshreds) >= 3
    {
        if ComboPoints() >=5 and BuffRemains(SAVAGEROAR) <={target.DebuffRemains(RIP)}
            Spell(SAVAGEROAR)
    }
    
    # aggressive FB
    if ComboPoints(more 4) and target.DebuffRemains(RIP) >=8 Spell(FEROCIOUSBITE)
}

AddFunction Fillers
{        
    # Shred aggressively for Berserk and TF
    if BuffPresent(BERSERK) or BuffPresent(TIGERSFURY) AddCombo()
    
    # Shred for combo points for Rip or SR
    if ComboPoints(less 5) and TargetDebuffExpires(RIP 3) AddCombo()
    if ComboPoints(less 1) and BuffExpires(SAVAGEROAR 2) AddCombo()
    
    # Shred to burn off energy so we can TF without capping
    if { 4s before Spell(TIGERSFURY) } AddCombo()
    
    # Fallback Shred to prevent energy capping
    if 1.4s before Energy(more 99) AddCombo()
}

# Main rotation
AddIcon help=main mastery=2 {
    RefreshSavageRoar()
    TFBerserk()    
    if not TargetInRange(SHRED) Texture(ability_druid_catformattack)
    MainRotation()
    if BuffPresent(CLEARCASTING) AddCombo()
    DesyncFB()
    Fillers()
}

# Predictive rotation
AddIcon help=predictive mastery=2 checkboxoff=predictive {
    RefreshSavageRoar()
    MainRotation()
    DesyncFB()
}


AddIcon help=cd size=small mastery=2 checkboxon=cooldownsR { # Rake
    if BuffExpires(SAVAGEROAR 0) Spell(SAVAGEROAR)
}
AddIcon help=cd size=small mastery=2 checkboxon=cooldownsR { # Rip
    if TargetDebuffExpires(RIP 0) Spell(RIP)
}
AddIcon help=cd size=small mastery=2 checkboxon=cooldownsR { # Rake
    if TargetDebuffExpires(RAKE 0) Spell(RAKE)
}
AddIcon help=cd size=small mastery=2 checkboxon=cooldownsR {
    Spell(TIGERSFURY)
}

[Mihir]

Sweet, can't wait to try it tonight!

[Konungr]

Why does your script force use of Glyph of Shred, it's bad and unneeded... Both Rebirth and Stampeding Roar are more situationally better.

[Tinderhoof]

The script assuming that you have Glyph of Shred isn't a bad deal. I would advise that no one use it except for Ultraxion. However having the script assume that you have it won't hurt anything. It will always tell you to shred anyway. It does help a lot though when you turn off "use Shred for fillers" for Ultraxion because it will remind you to Shred during TF and Berserk.

[Leafkiller]

I was in a hurry and did not put in a test for Glyph of Shred, I simply coded assuming it was there. It only matters if you turn off Shred as a filler for Ultraxion and don't have the glyph. Then you will see Shred recommended when TF and Berserk are up.

I was making code changes while I was in an LFR...

I will look through some of the comments in the other thread. This rotation was put together very fast just to have something that was working. Where I had issues, I simply nuked things. For example I nuked the aggressive FB code outside of Berserk. When that was enabled, I had long periods where I could not get Rip up. We have a lot less available energy now and have to be more careful how we use it.

[Sorcerer]

Minor tweaks needed:

- Pooling energy so you can have higher uptime on rake. Sometimes script was suggesting sth else just before rake was about to fall off
- FF script seems to not work properly, its being suggested over other DPS moves when its already up and you are during berserk/max energy or close to energy cap...

[Tinderhoof]

Just to make sure we are not having confusion can you tell us if you are using the script on the Beta or Live. Also what version of the script are you running? The reason I ask is the first script Leaf posted was suggesting FF every time it was off cooldown (7 seconds). This was fixed with the most recent update in this thread.

[Sorcerer]

Live Realm , Beta newest Ovale, newest script. Taken 1.5h ago.

[Mathoran]

Having the same issue with the script suggesting FF constantly.

on Live running 5.4.3

Only noticed it in LFR. Could it be that since FF has 2 components now if someone else casts it and overwrites your weakened armor debuff it thinks you need to refresh it?

ps. Thank you for all your work on this script it is appreciated.

[Leafkiller]

I would suggest that everyone using the script disables the FF option. I think the issue is either Ovale or an in-game bug. The script itself is pretty simple - it just calls for FF is the armor debuff stack is less than 1...And yes, I am checking for the armor debuff stack and not for FF.

[Sorcerer]

We are running 3 ferals tonight, so issue might be that ovale doesnt track your overriden FF casted by other druid.

Might be BEAR FF has different ID than feral.

1 Major thing, I really only felt sth was wrong was on ultraxion. I will provide log later as I tried to go by ovale asking to FF waaay too early.

Log http://www.worldoflogs.com/reports/viac ... 714&e=2927
I was tanking 2nd half of the fight so you can cut the log in half looking for right query.

[Leafkiller]

The script looks for the weakened armor debuff which has nothing to do with the FF spell ID. Also, the FF spell ID is the same for all druids now and works in any form/mastery.

[Mihir]

Just cleared DS25H with it, worked pretty well. Updated halfway the raid with the new version but still getting the FF problem. Other than that I didn't have much issues

[Leafkiller]

I just put in a slightly modified version, but I don't have time to test it, so it could be completely broken if I fat fingered anything. Someone please give it a try.

I am thinking of changing the default on FF to off, and based on feedback I recommend everyone turn off that option for kitties. Also, I added a new opportunistic FF call at the end of the script that will call FF when the weakened armor debuff has less than 15 seconds to run. This will occur during energy pooling, and it seems like a good way pf handling FF once the fight is going. This call is not subject to the FF disable switch so even if you turn that off, you will still be refreshing it during energy pooling times.

[Silvertip]

Im still getting used to all the changes, but ive been trying it on the dummy for a little while here, and it seems to be working pretty well. It still is giving me FF to often, but I just shred through it, and after a bit it goes away, and I resume attacking as usual. I am not getting any Ferouicious bite recomends though.
D

[Leafkiller]

You will only get FB during BitW or during Berserk now.

[Leafkiller]

It looks like there is now a 5.04 released version of Ovale on Curse.

[BoldTM]

Regarding Tigers Fury and energy. So we are only looking for T13 in order to determine the energy level. Should we not also look at if Berserk is on CD? We propably should also look for SotF as well if we are close to 5 points of something. I noted when doing some test rotation on dummy that i was energy capped using the 26 value.

[Vekz]

Is anyone else not having Savage Roar come up when it needs to be refreshed? And the Rip refresh timer is weird, it seems to prioritize FB over Rip, even if there's less than 5 seconds left on its duration.

[Leafkiller]

Is anyone else not having Savage Roar come up when it needs to be refreshed? And the Rip refresh timer is weird, it seems to prioritize FB over Rip, even if there's less than 5 seconds left on its duration.

Where you on a target dummy that only had a single hit point?

[Leafkiller]

Regarding Tigers Fury and energy. So we are only looking for T13 in order to determine the energy level. Should we not also look at if Berserk is on CD? We propably should also look for SotF as well if we are close to 5 points of something. I noted when doing some test rotation on dummy that i was energy capped using the 26 value.

I am not sure what you are suggesting with regards to TF. Sims have always shown it is best to use it as often as possible. Perhaps you can clarify.

Since TF is giving you an ooc proc, it is very tight to not energy cap. Keep in mind that since TF is not on the GCD, you can cast it at the same time (or very close to the same time) as your next attack. This is your best bet to avoid energy capping. If I put the value too low, then TF will be delayed more and you will not get as many TFs in depending on the fight. Since the current script has not been simmed I don't know what the proper value is, but 26 is likely close.

I am not inclined to spend much time micro-optimizing a rotation that is only useful for 4 weeks of play time. It just needs to be good enough to bridge people to MoP.

[Vekz]

Is anyone else not having Savage Roar come up when it needs to be refreshed? And the Rip refresh timer is weird, it seems to prioritize FB over Rip, even if there's less than 5 seconds left on its duration.

Where you on a target dummy that only had a single hit point?

D'oh, I didn't even realize. Of course Rip would act that way, but SR is still not functioning properly.

[BoldTM]

I am not inclined to spend much time micro-optimizing a rotation that is only useful for 4 weeks of play time. It just needs to be good enough to bridge people to MoP.

True and i agree. It was just that i noticed when Tigers Fury was lined up with Berserk i noticed energy capping. So i added a check if Berserk was off CD i just used 10 and i did not energy cap.
Regarding Soul of the Forest, it gives you 20 energy back and if we are aligning Rip to TF then we will have one ClearCasting and then one move that cost us 5 energy.

But yes optimizing now is pretty useless.

[mineko]

I took the script for a ride in H25 DS for the first time tonight and had a few oddities sprout up that weren't present while fighting a dummy:

First, as it looks like you're aware, having the FFF option turned on made it suggest FFF repeatedly for the whole fight until I turned it off. That seemed to resolve the problem.

Second, while fighting some enemies like the tentacle trash in Zon'ozz's room, it would suggest the "too far away" paw icon, even when I was standing on top of my target. When I switched targets to something else, it seemed to be resolved until the next trash pack.

Third, as we started Ultraxion, I unchecked the "use shred for fillers" box, but this seemed to break everything and it was suggesting for me to do nothing but savage roar every now and then. I got around it by checking the "use shred for fillers" box again and just mangling when it wanted me to shred.

[Terias]

I'm not entirely sure, because I haven't installed ovale to play around with it yet, but in the droodfocus thread they were having the same issue with ff (wasn't properly showing it up at all). The solution there was to turn on "show others debuffs" in the buffs/debuffs category. Maybe that's the same issue this script is having with FF?

As for the second issue, that's always happened. Just have to drop target and retarget to fix it - it happens anytime your character enters a 'vehicle' - and targets the mob before you get off of the vehicle (or still have it targeted). Happened every time I did bethtilac with ovale, would target before the web would get to the top and drop me off, and it'd be stuck on the paw icon until I retargeted it. It's probably because the big tentacle threw you.